[gradle] Java6 Annotation Processing

  • QueryDsl(JPA)を例に GradleでAnnotation Processingを実行させてみる
  • antの例があるので、ほぼこのままだったりするけど。。

annotation processingとは

dependenciesの設定

  • Annotation Processorを含むjarに対する依存関係を設定する。QueryDslは本体機能へのAPI(querydsl-jpa.jar など)とは別に、Annotation処理のjarが切り出されている(querydsl-apt.jar)。querydsl-apt.jarは、実行時には不要であるため、独自にdependency condfigurationを設定した。(下記processor)

 configurations {
      processor {
          description: "classpath for annotation processors"
      }
  }
  • dependenciesクロージャで、processorquerydsl-apt.jar を指定する
 dependencies {
      compile "org.eclipse.persistence:javax.persistence:2.0.0"
      compile "org.eclipse.persistence:eclipselink:2.4.0"
      compile "com.mysema.querydsl:querydsl-jpa:2.7.2"
      compile "org.slf4j:slf4j-log4j12:1.6.6"

      processor "com.mysema.querydsl:querydsl-apt:2.7.2"
  }

antのjavac呼出タスク定義

  • Annotation Processingの出力先は、build/processorGen/srcとした。今回は拡張プロパティext.destdirに設定しておく。

task execProcessor {
      ext.destdir = new File(buildDir, "processorGen/src")
      // ...
  }
  • buildディレクトリ配下としたのは、cleanタスクで消してくれるため。例えばモデルクラスの名前を変更すると旧名のメタクラスが残ったままになってしまうなど、cleanできたほうが都合がよい。

  • もちろん毎回消して再生成もよいのだけど、今回はUP-TO-DATEを仕掛けてビルドを効率化したかった。
  • UP-TO-DATEは下記のように inputsとoutputsにそれぞれファイルまたはディレクトリを設定することで、変更の有無(つまりAnnotation Processingタスクの実行が必要かどうか)をGradleが判定してくれるようになる。

 task execProcessor {
      ext.destdir = new File(buildDir, "processorGen/src")
      inputs.source(sourceSets.main.java)
      outputs.dir(ext.destdir)
      doLast{ /* ここにjavacを呼び出す処理 */ }
  }
  • doLastクロージャで、このタスクの実行処理を記述する。この例ではantjavacを呼び出してみる。

doLast {
      ext.destdir.mkdirs() // 出力先が事前に存在しないとエラーになるのを回避

      def primaryOptions = [
          includeAntRuntime: false,
          destdir: ext.destdir,
          classpath: configurations.compile.plus(configurations.processor).asPath,
      ]

      ant.javac(primaryOptions) {
         sourceSets.main.java.addToAntBuilder((Object)ant, 'src', FileCollection.AntType.MatchingTask)
         compilerarg(value: "-proc:only") 
         compilerarg(value: "-implicit:none")
         compilerarg(value: "-processor")
         compilerarg(value: "com.mysema.query.apt.jpa.JPAAnnotationProcessor")
      }
  }
  • 上記のant.javacはおおよそ下記のようなant記述と同じ意味

    <javac includeAntRuntime=false
           destdir="${ext.destdir}"
           classpathref="${compiler.plus(processor).asPath}">
      <src ...ここはaddToAntBuilder()がゴニョゴニョする  />
      <compilerarg value="-Xlint"/>
      <compilerarg value="-proc:only"/>
      <compilerarg value="-implicit:none/>
      <compilerarg value="-processor/>
      <compilerarg value="com.mysema.query.apt.jpa.JPAAnnotationProcessor/>
    </javac>

compileJavaの設定

  • これで execProcessorを実行すればQueryDslによってメタクラスがbuild/processorGen/srcに生成される。だがこのソースが compileの対象になっていないのでこのままではコンパイルされない。
  • ここで src/main/javaディレクトリにコピーするという手もあるが、UP-TO-DATE判定を考えると好ましくない。また、Checkstyleといった静的解析ツールが処理する対象ディレクトリから自動生成されたコードを分離したいということもあるかもしれない
  • ということで、compileJavaの対象ソースディレクトリとして execProcessorの出力先ディレクトリを追加する。
  • また、compileJavaの依存タスクとして execProcessorを設定する。

compileJava {
      dependsOn execProcessor
      source execProcessor.ext.destdir
 }

これでcompileJavaを実行するとexecProcessorが先に実行される。

$ gradle compileJava
:execProcessor
[ant:javac] 注意:Running JPAAnnotationProcessor
[ant:javac] 注意:Serializing Entity types
[ant:javac] 注意:Generating .... for [...]
[ant:javac] 注意:Running JPAAnnotationProcessor
[ant:javac] 注意:Running JPAAnnotationProcessor
:compileJava

BUILD SUCCESSFUL

また、変更がなければ UP-TO-DATEと判定され、実行されない。

$ gradle compileJava
:execProcessor UP-TO-DATE
:compileJava UP-TO-DATE

BUILD SUCCESSFUL

[gradle] TaskとAction

自分がGradleでハマッたポイントを晒してみる

task copyTaskA(type: Copy) {
  from 'src/main/webapp'
  into 'build/explodedWar'
}

task copyTaskB {
  copy {
    from 'src/main/webapp'
    into 'build/explodedWar'
  }
}

上のcopyTaskAとcopyTaskBは同じだと思って何気なく書いていたのだが、しばらくしてcopyTaskBのコピーが、依存タスクに関係なく、いつでも実行されてしまっていることに気づいた。

結論をいうと、copyTaskAと同等のタスクにするには << が必要だった。

task copyTaskA(type: Copy) {
  from 'src/main/webapp'
  into 'build/explodedWar'
}

task copyTaskB << {
  copy {
    from 'src/main/webapp'
    into 'build/explodedWar'
  }
}

こたえはここに書いていた。
Example 48.1. Single project build
つまりこういうことらしい

task configured {
  // ここは、タスク自体のプロパティを設定するところ
  // gradleの実行時にすべてのタスクで評価が行われる
}

task actionAdded << {
  // ここは、actionAddedタスクが直接的に呼び出されたり、依存元タスクが呼びされれたりすると実行される
}

では、taskに << {}するとは何なのか。ここでGradle DSLのドメインモデルを。


Gradleでは、Project、Task、Actionのような階層になっていて、Taskは Actionオブジェクトのシーケンスを持ってる。<<演算子は、そのシーケンスにActionを追加する。また、Taskの doFirstとdoLastメソッドでActionを追加することも可能。たとえばcompileの前にファイルコピーをしたかったらこのように書く。

compile.doFirst {
  copy {
    from 'otherdir/othersrc'
    into 'src/main/java'
  }
}

ちなみにここのcopyは Projectクラスのメソッドであり CopyTask (一番最初にcopyTaskA(type: Copy)と書いたもの)とはまったく関係ない。Projectクラスのメソッドは build.gradle内のどこからでも呼べることになっている(たしか。原典みつからず)というルールで実現されている。task myTask {…} の taskも同じ。

話はそれるが、~の前にしたいコピーをタスクにして依存関係を持たせることもできる。compileタスクが実行される前にmyCopyが実行される点は同じだが、myCopy単独で実行もできる(Taskなので。)

task myCopy << {
  copy {
    from 'src/main/webapp'
    into 'build/explodedWar'
  }
}
compile.dependsOn(myCopy)

参考までに

[gradle] Eclipse Gradle STS Support と gradle-gae-plugin

はじめに

Gradleが気になっていたので使ってみたメモ。
Eclipseと統合されているのがよいので、Eclipseの拡張機能(Gradle STS Support)を試してみた。
ついでにGoogle App Engineのアプリケーションをgradleからデプロイする方法も試してみた
今回試したのは下記のバージョン。

セットアップ

Gradleのサイトによると、SpringSourceのSTS(Spring Tools Suite)にGradleサポート機能があり、Gradle機能だけを個別にインストールできるとのこと。Springを使うわけではないのに(いや、使うにしても)重量級のSTSを入れなくてもすむのは助かる。

Gradle STS Supportのインストール方法はGradle STS Support — 2.9.0 — Installation(英語)の通り。一緒に gradle-1.0-mileston-7 もプラグインとしてインストールされるので、gradle自体のインストールは不要(※単なるJavaプロジェクトならこれでも十分だと思うが、実際は gradle-gae-pluginが動かなくて結局別のバージョンを使った。詳しくは後述する)

まずはeclipseでプロジェクト構成を作る。デフォルトのディレクトリ構造にしておくと(もちろん変更できるが)面倒が少ない。webアプリケーションのファイル(jspなど)はwarプラグインのデフォルトディレクトリ構造にしておく。

で、build.gradleを書いて、プロジェクトのディレクトリ直下に置く。GAEとslim3を使う場合はこのような例に。

build.gradle
apply plugin: 'java'

def gaeVersion = '1.6.4'
def slim3Version = '1.0.15'

repositories {
    mavenCentral()
    mavenRepo(url: 'http://maven.seasar.org/maven2/')
}

dependencies {
    compile 'javax.servlet:servlet-api:2.5'
    compile 'javax.servlet:jsp-api:2.0'
    compile "com.google.appengine:appengine-api-1.0-sdk:$gaeVersion"
    compile "com.google.appengine:appengine-api-labs:$gaeVersion"
    compile ("org.slim3:slim3:$slim3Version") {
        exclude group: 'com.google.appengine', module: 'appengine-api-1.0-sdk'
    }
}

Gradle STS Support — 2.9.0 — Tutorial(英語)に使い方は書いてあるが、下記に簡単に書く

  • (チュートリアルではImportを使っているが、)プロジェクトの右クリックメニュー→[Configure]→[Convert to Gradle Project]をすると、Gradleプロジェクトとして認識される。チュートリアルに出てくるような「G」マークがプロジェクトに付くようになる
  • build.gradleを右クリックメニュー→[Gradle]→[Enable Dependency Management]を選ぶと、ビルドパスに[Gradle Dependencies(persisted)]というLibraryが追加され、build.gradleに書いた依存関係にあるjar(dependencies {…}に書いたslim3-1.0.15.jarなど)が追加される。
    • なお、build.gradleのdependenciesの記述を更新しても自動的には反映されない。手動で[Gradle]->[Refresh Dependencies]を実行する必要がある
  • Gradle Tasks Viewを開き、[Project]を選択すると、タスク一覧が表示される。たとえば compileJava をダブルクリックすればGradleによってコンパイルが動作する
  • もちろん、Eclipseのビルドパスにjarが追加されているのでEclipseでのコンパイルもできる

Google Eclipse Pluginでのデプロイには、warディレクトリを構成しなくてはいけないので、そういうCopyなどのタスクを定義するというやり方もあるだろう。
しかしもう少しスマートに gradleから Google App Engineに Deployする方法を書く。この方法だとGoogle Eclipse Pluginは特に不要である。

gradle-gae-plugin

gradleは汎用的に設計されたビルドツールであり、例えば javaをビルドしたいときは apply plugin: 'java' と記述して、 java プラグインを適用する。javaやscalaなどの標準で組み込まれているプラグインが多数あるが Google App Engineのプラグインは標準にはない。今回使用するgradle-gae-pluginはbmuschko氏のサードパーティ製プラグインである。
使い方は簡単で、readmeにあるとおり下記をそれぞれ追加するだけである。(7/7 0.7.3時点のreadmeに修正。今はグループIDがorg.gradle…になり、maven central repositoryから取得可能となった)

pluginを指定する

apply plugin: 'gae'

buildscriptを記述する

buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath 'org.gradle.api.plugins:gradle-gae-plugin:0.7.3'
    }
}
ちなみに:

buildscriptdependenciesには、このgradleビルドスクリプトを動作させるために必要なライブラリへの依存関係を解決するためのもので、サードパーティのプラグインをここで定義する。先に述べたdependenciesのcompileなどに定義しても動くと思うが、compileに定義したjarは war/WEB-INF/libの下に含まれてしまう。gradle pluginや、例えば slim3-gen.jarのようなビルドスクリプト動作時にのみ必要なライブラリはここに書くのがよい。

さてここで EclipseのGradle Tasks Viewを更新する。(矢印が回転しているアイコンのボタンをクリック。ツールチップに「Refresh task list」とでる)
すると、下記のエラーになって止まってしまう。

org.gradle.internal.service.ServiceRegistry
Could not fetch model of type 'EclipseProject' using Gradle distribution 'http://repo.gradle.org/gradle/distributions/gradle-1.0-milestone-7-bin.zip'.

ここでEclipseのメニューバー[Window]→[Preferences]→[Gradle]のGradle DistributionのURIに

と入力したところ、うまく動作した。

現象的にはGRADLE-2185の問題に近いと思われる。
実際、いろいろ調べている間、milestone-9で上記同様の指定をしたのだがうまく動かなかった。そのうちrc-1がリリースされて試してみたらうまくいった。

Gradle Tasks Viewに gaeXxxというタスクが並んで見えるようになるはず。
デプロイの場合は、その中のgaeUploadというタスクを実行し、appspotのログインID(emailアドレス)やパスワードを入れるとデプロイができる。他のタスクについては、readmeを参照のこと。

gaeDownloadSdkについて

Google App EngineのSDKをどこかに展開している人は、環境変数のAPPENGINE_HOME または システムプロパティの google.appengine.sdk にパスをしていしておけばよいが、gradle-gae-pluginにはSDKをダウンロードしてくるタスクもある。これでどの環境でも同じSDKのバージョンを使用することになるし、SDKのバージョンアップもGradleのビルドスクリプトだけで完結する。

依存関係として、gaeSdk configurationに、GAEのSDKを指定する。

dependencies {

    //compile .......
    //  ..... 

    gaeSdk "com.google.appengine:appengine-java-sdk:$gaeVersion"
}

gae.downloadSdk = trueを指定する

gae {
    downloadSdk = true
}

それから、gradle-gae-pluginのバグなのか、二回目以降のビルドで gaeDownloadSdkがUP-TO-DATEの時にSDKパスがAPPENGINE_HOME にも google.appengine.sdkにも指定されていないというエラーとなってしまうので、自分はこのように設定している
(7/7訂正 0.7.3で確認したところsystem propertiesの設定は不要になっていた。バグだったのがFIXされた模様)

gae {
    downloadSdk = true
    System.properties['appengine.sdk.root'] = gaeDownloadSdk.explodedSdkDirectory.getPath() + File.separator + "appengine-java-sdk-$gaeVersion"
}

4/18追記
gaeUploadの途中でemailとpasswordを聞かれ、Eclipseのコンソールに入力すると動作していたのだが、最近うまく動かなくなったので回避策を。

build.gradleのgae{}にappcfg{}を定義して、emailとpassIn=trueを設定。
※ここにpassword=xxxxxxxと入れてもよいが、build.gradleはリポジトリに入れてるので外だしにする。

gae {
    appcfg {
        email = 'your_email_address@gmail.com'
        passIn = true
    }

    downloadSdk = true
    System.properties['appengine.sdk.root'] = gaeDownloadSdk.explodedSdkDirectory.getPath() + File.separator + "appengine-java-sdk-$gaeVersion"
}

~/.gradleディレクトリ(Windows 7の場合は C:\Users\ryo-murai\.gradleなど)にgradle.propertiesファイルを置いて、下記のように書く。

gradle.properties

gaePassword=your_google_password

これで、指定したemail/passwordが使用される模様。
追記おわり

まとめ

  • EclipseとGradleの統合に、EclipseプラグインであるGradle STS Supportを使ってみた
  • Google App Engineへのデプロイにgradle-gae-pluginを使ってみた
    • Gradle STS Support同梱の gradle-1.0-milestone-7では動かないので、1.0-rc-1を指定する
  • gaeDownloadSdk使ってもSDKへのパス設定が必要だった。(オレだけ?)

補足

この記事のリンクは
gradle-1.0-rc-1のマニュアルやGradle STS Support 2.9.0のドキュメントを参照しているが、GradleはURLの /docs/1.0-rc-1/userguide//docs /current/userguide/に、またSTSは/sts/docs/2.9.0/reference//sts/docs/latest/reference/に変更すると、最新のバージョンのドキュメントへのURLとなる。